LastUPDATE '07.11.30(新規作成); UPDATE '07.11.30(新規作成); New '07.11.30(新規作成)

結果を詳しく検討するには，CIRファイルから回路図を再現してください


三種のマルチバイブレータ

  1. 回路図とダウンロードデータへのリンク
  2. 注釈
  3. シミュレーションの手順や，シミュレーション時の考察点
  4. ダウンロードデータ（回路図をサーキットファイルで記述したもの）
1. 回路図とダウンロードデータへのリンク

Download circuit f161
2. 注釈
回路に関する注釈：
  1. トランジスタを 6 個備える。（ Q1 ～ Q6 ）
  2. Q1 と Q2 からなる回路は，無安定マルチバイブレータ（astable multivibrator）である。
  3. Q3 と Q4 からなる回路は，単安定マルチバイブレータ（monostable multivibrator）である。
  4. Q5 と Q6 からなる回路は，双安定マルチバイブレータ（bistable multivibrator）である。
  5. Q1 ～ Q6 それぞれのコレクタ電圧を VC1 ～ VC6 と呼ぶことにする。【図にVC1の例を示す】
  6. Q1 ～ Q6 それぞれのベース電圧を VB1 ～ VB6 と呼ぶことにする。【図にVB1の例を示す】
  7. ダイオードを 3 個備える。（ D1 ～ D3 ）これらは，トリガ信号のための回路を作っている。
  8. D1 ～ D3 それぞれの端子を VD1 ～ VD3 と呼ぶことにする。【図にVD1の例を示す】
  9. トランジスタ Q1 ～ Q6 のコレクタから正電源まで繋がる6本の抵抗 R1, R3, R5, R7, R9, R11 はどれも 1kΩ
  10. 抵抗で，前項に当てはまらないものは，どれも30kΩ
  11. コンデンサ C1 = C2 = 47nF
  12. コンデンサ C3 = 22nF
  13. コンデンサ C4 = C5 = C6 = 4.7nF
  14. コンデンサ C7 = C8 = C9 = 1.0nF
  15. コンデンサ C1，C2，C3 は，実験用の基板では脇に端子を備える。 その端子に別のコンデンサを差し込むことで，容量値を増加できる。
3. シミュレーションの手順や，シミュレーション時の考察点
回路 nf161 は，ngspice において「三種のマルチバイブレータの動作」を動作させて理解する教材です。

回路 ne161 をシミュレーションするための操作
  1. ngspice を使える環境を用意する。
    （2007年12月時点で，沼津高専の情報処理教育センターではどの端末からでも ngspice を走らせることができます。
     また，このウエブ内で，ngspice のインストール方法も書かれているので，参考にして自分のパソコンにインストールすることもできます。）

    【前準備】
  2. この文書の回路図のところから，circuit f161 すなわち「nf161.cir」というファイルを，自分が使うパソコン上にダウンロードする。
    なお，ダウンロード先は，私の場合，「c:\ngspice\nf161.cir」である。
    注意すべきは，ファイル名も，パス中のフォルダ名も，半角の英数字のみが許されるということである。これは ngspice が開発されたのが日本でないことが理由だと思われる。

    【使用手順の説明】
  3. ngspice を起動する
  4. 「file」＞「open」から ne161.cir を開く
  5. 「file」＞「run」 コマンドによりミュレーションを実行させる
  6. 「Graph」＞「Select Vector」コマンドを選ぶ
    --->すると，表示すべき電圧を聞いてくる。
  7. vb1  vc1      と打ち込む
    --->すると，グラフを描いてくれる。
  8. 「Command」＞「Edit source」とすると，シミュレーション中の回路ファイルのテキスト編集が始める。
    --->（テキストエディタの中で）例えば C1 の値を変えるなど，必要に応じて編集しよう。
  9. テキストエディタを終了する。
    --->すると，ngspiceは「run circuit」と聞いてくる。
  10. Enter キーをたたく
    --->すると，シミュレーションが実行される。これは「file」＞「run」 コマンドの発行と同じである。
  11. これ以降，以上で述べた「手順6」～「手順10」を繰り返すことで，シミュレーションが続けられる。
  12. 「file」＞「exit」 コマンドによりngspiceを終了する。

    【課題-I】
  13. astable型のマルチバイブレータのグラフを書かせたいなら，上記手順7の時に，
    vb1  vc1  vb2  vc2
    と打ち込む。このとき，同じ電圧付近にグラフが集まってしまうので，例えば
    vb1+10  vc1+10  vb2  vc2
    と打ち込めば，Vb1 と Vc1 については本来の電圧よりも 10[V] 高い電圧として表示してくれるので，グラフが見やすくなる。
  14. C1を変更したとき，どのタイミングがどのように変化するだろうか。（例：47nF → 94nF）
  15. C2を変更したとき，どのタイミングがどのように変化するだろうか。（例：47nF → 94nF）
  16. astable型の動作原理を考えてみよう。

    【課題-Ⅱ】
  17. monostable型のマルチバイブレータのグラフを書かせたいなら，上記手順7の時に，
    vc2  vb3  vc3  vb4  vc4
    と打ち込む。vc2 はトリガ信号なので，一緒に表示するべきである。同じ電圧付近にグラフが集まるのを避けるには，例えば
    vc2+10  vb3  vc3  vb4-10  vc4-10
    と打ち込む。
  18. C3を変更したとき，どのタイミングがどのように変化するだろうか。（例：22nF → 69nF）
  19. monostable型が動作するトリガは，Vc2 のどういう変化だろうか。
  20. monostable型の動作原理を考えてみよう。

    【課題-Ⅲ】
  21. bistable型のマルチバイブレータのグラフを書かせたいなら，上記手順7の時に，
    vc2  vb5  vc5  vb6  vc6
    と打ち込む。vc2 はトリガ信号なので，一緒に表示するべきである。同じ電圧付近にグラフが集まるのを避けるには，例えば
    vc2+10  vb5  vc5  vb6-10  vc6-10
    と打ち込む。
  22. bistable型が動作するトリガは，Vc2 のどういう変化だろうか。
  23. bistable型の動作原理を考えてみよう。
  24. もしもダイオードD3を外してしまって，D2からの信号にみがbistable型に届いたとしたらどうなるか考察せよ。
    （D3の行の１文字目を「*」（アスタリスク）にすると，D3を回路から外したことになる。（アスタリスクから始まる行は注釈文として解釈される） この状態でシミュレーションしてみたら答えが分かる。）
  25. もしもダイオードD2を外してしまって，D3からの信号にみがbistable型に届いたとしたらどうなるか考察せよ。
    （D2の行の１文字目を「*」（アスタリスク）にすると，D2を回路から外したことになる。（アスタリスクから始まる行は注釈文として解釈される） この状態でシミュレーションしてみたら答えが分かる。）
  26. 上記手順24と手順25は，それぞれ「セット」と「リセット」とも呼ばれる操作である。

　

4. ダウンロードデータ（回路図をサーキットファイルで記述したもの）
* circuit three multuvibrators
.tran  10u 6m 0  
.ic V(VB1)=0.2  V(VB5)=0.2
* Vs   1   0   sin(0V  1mV  10kHz)
*
Vcc   9   0   DC  5V
*
* astable
Q1  VC1  VB1 0 Q2SC1815
C1  VC1  VB2   47n
R1    9  VC1   1k
R2    9  VB1   30k
*
Q2  VC2  VB2 0 Q2SC1815
C2  VC2  VB1   47n
R3    9  VC2   1k
R4    9  VB2   30k
*
*
* monostable
Q3  VC3  VB3 0 Q2SC1815
C3  VB3  VC4   22n
R5    9  VC3   1k
R6    9  VB3   30k
*
Q4  VC4  VB4  0 Q2SC1815
C4  VB4  VC3    4.7n
R7    9  VC4    1k
R8  VB4  VC3    30k
*
*
* bistable
Q5  VC5  VB5 0 Q2SC1815
C5  VB5  VC6   4.7n
R9    9  VC5   1k
R10 VB5  VC6   30k
*
Q6  VC6  VB6 0 Q2SC1815
C6  VB6  VC5   4.7n
R11   9  VC6   1k
R12 VB6  VC5   30k
*
*
* a to mono 
C7  VD1  VC2   1n
R13 VD1    0   30k
D1  VD1  VB3   d1s2075
R14   0  VB3   30k
*
* a to bi 
C8  VD2  VC2   1n
R15 VD2    0   30k
D2  VD2  VB5   d1s2075
R16   0  VB5   30k
*
C9  VD3  VC2   1n
R17 VD3    0   30k
D3  VD3  VB6   d1s2075
R18   0  VB6   30k
*
.probe
*-----------------------------------------------------
* copy from http://www.madlabo.com/mad/edat/spice/index.htm
*-----------------------------------------------------
* HItachi Si EP High speed switch
.model d1s2075	D(IS=1.387E-9 N=1.702 RS=1.53
+		CJO=1.92pf VJ=0.4996 M=0.0605 TT=5ns BV=75 IBV=100E-15)
*
*Low Noise Amp PC=0.4W Ic=0.15A Vcbo=60V
.model Q2SC1815 NPN(Is=2.04f Xti=3 Eg=1.11 Vaf=6 Bf=400 Ne=1.5 Ise=0
+ Ikf=20m Xtb=1.5 Br=3.377 Nc=2 Isc=0 Ikr=0 Rc=1 Cjc=2p
+ Mjc=.3333
+ Vjc=.75 Fc=.5 Cje=5p Mje=.3333 Vje=.75 Tr=10n Tf=311.1p
+ Itf=0 Vtf=0 Xtf=0)
*		TOSHIBA		90-01-29	creation
*
*Low Noise Amp PC=0.4W Ic=0.15A Vcbo=50V
.model Q2SA1015 PNP(Is=295.1E-18 Xti=3 Eg=1.11 Vaf=100 Bf=110 Ne=1.5 Ise=0
+ Ikf=0 Xtb=1.5 Br=10.45 Nc=2 Isc=0 Ikr=0 Rc=15 Cjc=66.2p
+ Mjc=1.054 Vjc=.75 Fc=.5 Cje=5p Mje=.3333 Vje=.75 Tr=10n
+ Tf=1.661n Itf=0 Vtf=0 Xtf=0)
* TOSHIBA 90-01-23	creation
*
* Ideal Operational Amplifier . . . K. Mochizuki 2002.3.15
* + - out
.subckt opamp00 1 2 3 params: av = 1000000, vcc=15
rin 1 2 1G
eout 3 0 value={max(-vcc min(vcc av*v(1,2) ) )}
rpow 3 4 1G
.ends
*-----------------------------------------------------
.END