LastUPDATE 06.2.3(NGSPICE for windows 用に全面的に書き換え) ,UPDATE 02/10/29(誤字脱字の修正) , UPDATE 02/03/18(物理系追加,Download設定) , UPDATE 02/03/14(一応の完成) , New 02/03/11(SPICE for linux用に製作)

第1問 直流電圧を加えた時の各部の電圧と電流

ファイル ' n11.cir ' の中身。他も同様。
Download
* circuit 11
.OP 
R1 1 2 1k 
V1 1 0 12V
R2 0 2 1k 
.probe
.END
回路 n11 をシミュレーションするための操作
(1) ngspice の起動
(2) 「file」>「open」から n11.cir を開く
(3) 「file」>「run」 コマンドによるシミュレーションの実行
(4) 「Command」>「Print ALL」コマンドを選ぶ
--->すると,ノード1 の電圧の 12.00 (V) と
 ノード2 の電圧の 6.00 (V) が表示される。
(5) "show r1 (enter)" と打ち込む
--->すると,素子 R1 を流れる電流の i=0.006 (A) が表示される。
(6) "show r2 (enter)" と打ち込む
--->すると,素子 R2 を流れる電流の i=-0.006 (A) が表示される。
注意:電流の符号が逆なのは,流れる方向の違い
(7) "show v1 (enter)" と打ち込む
--->すると,素子 V2 を流れる電流の i=-0.006 (A) が表示される。
(8) (お好みで)「Command」>「Edit source」から編集すればパラメタを変えられる。

・改造した n11 について,改めて SPICE でデータを取ろう
・自分がオームの法則を使って解いた結果と,SPICEの結果が合っているか,
 確認し,表を作って比較してみよう

共通する条件 V1=12V,R1=1kOhm

	条件 R2=1k(これはレポート不要)	条件 R2=2k (レポートに。値は自分で設定)
	V(2)	I(R1)	I(R2)		V(2)	I(R1)	I(R2)
理論	___	___	___		___	___	___
SPICE	___	___	___		___	___	___
誤差	___	___	___		___	___	___

--------------------------
回路n12, 回路n13 についても,同様に実験しよう

Webページ上に記載されたパラメタのままの結果は,レポートに記載する必要はありません。
必ずどこかのパラメタを変更し,そのパラメタと結果をレポートに記載するように。
(出席番号にちなんだ値への変更を基本とするが,
	人とかち合わないような難しい値への変更も歓迎する。)
Download
* circuit 12
.OP 
V1 1 0 12V
R1 1 2 1k 
R2 0 2 1k 
R3 0 2 1k 
.probe
.END
Download
* circuit 13
.OP 
V1 1 0 12V
R4 2 1 1k 
R5 3 1 3k 
R1 2 3 1k 
R2 0 2 3k 
R3 0 3 1k 
.probe
.END

注意:R2,R5は図と一致していません

第2問 周波数ごとの交流信号に対する入出力特性

Download
* circuit 21
.ac DEC 20 0.1 100K
V1 1 0 DC 0V AC 1V 
R1 1 2 1k 
C1 0 2 1u 
.probe
.END
回路 n21 をシミュレーションするための操作
(1) ngspice の起動
(2) 「file」>「open」から n21.cir を開く
(3) 「file」>「run」 コマンドによるシミュレーションの実行
(4) 「Graph」>「Select Vector」コマンドを選ぶ
--->すると,表示すべき電圧を聞いてくる。
 今回は周波数特性なので,縦軸は dB (デシベル)になる。
(5) db(v(1)-v(2)) db(v(2)) と打ち込む
--->他のグラフとして,次のようにも打ってみよう。
例1:20*log(v(2))
例2:vp(v(2))*180/3.14
注意 vp とは位相のこと
(6) (お好みで)「Command」>「Edit source」から編集すればパラメタを変えられる。

・改造した n21 について,改めて SPICE でデータを取ろう
・自分が回路理論を使って解いた結果と,SPICEの結果が合っているか,
 確認し,表を作って比較してみよう

共通する条件 V1=1V,C1=1uF (マイクロ ファラッド)

	条件 R1=1k Ohm		条件 R1=2k (自分で設定)
	カットオフ周波数		カットオフ周波数
理論		___			___
SPICE		___			___
誤差		___			___

--------------------------
回路n22〜n25 についても,同様に実験しよう

Webページ上に記載されたパラメタのままの結果は,レポートに記載する必要はありません。
必ずどこかのパラメタを変更し,そのパラメタと結果をレポートに記載するように。
(出席番号にちなんだ値への変更を基本とするが,
	人とかち合わないような難しい値への変更も歓迎する。)
Download
* circuit 22
.ac DEC 20 0.1 100K
V1 1 0 DC 0V AC 1V 
R1 1 2 1k 
C1 0 2 1u 
R2 0 2 100k 
.probe
.END
Download
* circuit 23
.ac DEC 20 0.1 100K
V1 1 0 DC 0V AC 1V 
C1 1 2 10u 
R1 0 2 1k 
C2 0 2 0.1u 
.probe
.END
Download
* circuit 24
.ac DEC 20 0.1 100K
V1 1 0 DC 0V AC 1V 
R1 2 1 1k 
C1 0 2 0.1u 
R2 3 2 100k 
C2 0 3 1u 
.probe
.END
Download
* circuit 25
.ac DEC 20 0.1 100K
V1 1 0 DC 0V AC 1V 
L1 1 2 1mH 
C1 0 3 10uF
R1 3 2 5ohm 
.probe
.END
回路 n25 をシミュレーションするための操作
(1) ngspice の起動
(2) 「file」>「open」から n25.cir を開く
(3) 「file」>「run」 コマンドによるシミュレーションの実行
(4) 「Graph」>「Select Vector」コマンドを選ぶ
--->すると,表示すべき電圧を聞いてくる。
 今回は周波数特性なので,縦軸は dB (デシベル)になる。
(5) db(v(1)-v(2)) db(v(2)-v(3)) db(v(3)) と打ち込む
(6) (お好みで)「Command」>「Edit source」から編集すればパラメタを変えられる。


・R1 の値を変更した n25 について,改めて SPICE でデータを取ろう
・自分が回路理論を使って解いた結果と,SPICEの結果が合っているか,
 確認し,表を作って比較してみよう

実験(あ) 共通する条件 V1, L1, C1=回路図通り
R1=	1	2	5	10	20	50 (Ohm)
SPICE	___	___	___	___	___	___ (Hz) カットオフ周波数
SPICE	___	___	___	___	___	___ (V) カットオフ周波数の v(3)
計算	___	___	___	___	___	___ (Hz) カットオフ周波数
計算	___	___	___	___	___	___ (V) カットオフ周波数の v(3)
	計算とは,理論を元に学生が計算すること

実験(い) 共通する条件 V1, R1
L1	0.1m	10m	100m	回路図	回路図	回路図 (H)
C1	回路図	回路図	回路図	1u	100u	1000u (F)
SPICE	___	___	___	___	___	___ (Hz) カットオフ周波数
SPICE	___	___	___	___	___	___ (V) カットオフ周波数の v(3)
計算	___	___	___	___	___	___ (Hz) カットオフ周波数
計算	___	___	___	___	___	___ (V) カットオフ周波数の v(3)
	計算とは,理論を元に学生が計算すること
	回路図とは,回路図とおりということ
--------------------------
回路n25に関しては,ここに記載したパラメタも含めてレポートに記載するように。

第2問(別解)周波数ごとの交流信号に対する入出力特性

Download
* circuit 21f

.tran 0 100m 0 30u
V2  11  0  sin(0V  0.3V  30Hz)
V1  1  11  sin(0V  0.3V  3KHz)

*.ac DEC 20 0.1 100K
*V1  1  0  DC  0V  AC  1V

R1  1  2  1k 
C1  0  2  1u 
.probe
.END

回路 n21f をシミュレーションするための操作
(1) ngspice の起動
(2) 「file」>「open」から n21f.cir を開く
(3) 「file」>「run」 コマンドによるシミュレーションの実行
(4) 「Graph」>「Select Vector」コマンドを選ぶ
--->すると,表示すべき電圧を聞いてくる。
(5) v(1) と打ち込む
--->他のグラフとして,次のようにも打ってみよう。
例1:v(2)
例2:v(1)-v(2)
(6) (お好みで)「Command」>「Edit source」から編集すればパラメタを変えられる。

・改造した n21f について,改めて SPICE でデータを取ろう
・自分が回路理論を使って解いた結果と,SPICEの結果が合っているか,
 確認し,表を作って比較してみよう

解説:ここでは正弦波を入れて実際の波形を観察した。
その際,2つの周波数が信号源になるように,新たにノード11を加えた。

第3問 ステップ関数入力に対する回路の時間応答


(n21と同じ回路)
Download
* circuit 31
.tran 30u 60m 0 30u
V1 1 0 pulse(0V 1V 5ms 0 0 10ms 30ms) 
R1 1 2 1k 
C1 0 2 1u 
.probe
.END
回路 n31 をシミュレーションするための操作
(1) ngspice の起動
(2) 「file」>「open」から n31.cir を開く
(3) 「file」>「run」 コマンドによるシミュレーションの実行
(4) 「Graph」>「Select Vector」コマンドを選ぶ
--->すると,表示すべき電圧を聞いてくる。
 今回は時間特性なので,縦軸はリニアな目盛りである。
(5) v(1)-v(2) v(2) と打ち込む
(6) (お好みで)「Command」>「Edit source」から編集すればパラメタを変えられる。
= = = R1の値を変更 = = =

・改造した n31 について,改めて SPICE でデータを取ろう
・自分が回路理論を使って解いた結果と,SPICEの結果が合っているか,
 確認し,表を作って比較してみよう

共通する条件 V1=1V,C1=1uF (マイクロ ファラッド)

	条件 R1=1k Ohm	条件 R1=2k (自分で設定)
	収束時間		収束時間
理論	___		___
SPICE	___		___
誤差	___		___

--------------------------
Webページ上に記載されたパラメタのままの結果は,レポートに記載する必要はありません。
必ずどこかのパラメタを変更し,そのパラメタと結果をレポートに記載するように。
(出席番号にちなんだ値への変更を基本とするが,
	人とかち合わないような難しい値への変更も歓迎する。)

(n25と同じ回路)
Download
* circuit 32
.tran 30u 60m 0 30u
V1 1 0 pulse(0V 1V 5ms 0 0 10ms 30ms) 
L1 1 2 1mH 
C1 0 3 10uF
R1 3 2 5ohm 
.probe
.END
回路 n32 をシミュレーションするための操作
(1) ngspice の起動
(2) 「file」>「open」から n32.cir を開く
(3) 「file」>「run」 コマンドによるシミュレーションの実行
(4) 「Graph」>「Select Vector」コマンドを選ぶ
--->すると,表示すべき電圧を聞いてくる。
 今回は時間特性なので,縦軸はリニアな目盛りである。
(5) v(1)-v(2) v(2)-v(3) v(3) と打ち込む
(6) (お好みで)「Command」>「Edit source」から編集すればパラメタを変えられる。

・改造した n32 について,改めて SPICE でデータを取ろう
・自分が回路理論を使って解いた結果と,SPICEの結果が合っているか,
 確認し,表を作って比較してみよう

実験(あ) 共通する条件 V1, L1, C1=回路図通り
R1=	1	2	5	10	20	50 (Ohm)
SPICE	___	___	___	___	___	___ (s) 収束時間
SPICE	___	___	___	___	___	___ (s) 振動の場合,周期
計算	___	___	___	___	___	___ (s) 収束時間
計算	___	___	___	___	___	___ (s) 振動の場合,周期
	計算とは,理論を元に学生が計算すること

実験(い) 共通する条件 V1, R1
L1	0.1m	10m	100m	回路図	回路図	回路図 (H)
C1	回路図	回路図	回路図	1u	100u	1000u (F)
SPICE	___	___	___	___	___	___ (s) 収束時間
SPICE	___	___	___	___	___	___ (s) 振動の場合,周期
計算	___	___	___	___	___	___ (s) 収束時間
計算	___	___	___	___	___	___ (s) 振動の場合,周期
	計算とは,理論を元に学生が計算すること
	回路図とは,回路図とおりということ
--------------------------
回路n32に関しては,Webページ上に記載されたパラメタの場合も含めてレポートに記載するように。

第4問 他の分野への応用

(準備中) Download
* circuit 41
.tran 30u 60m 0 30u
V1 1 0 pulse(0V 1V 5ms 0 0 10ms 30ms) 
L1 1 2 1mH 
C1 0 3 10uF
R1 3 2 5ohm 
.probe
.END
注意:n32と全く同じです
物理系 n41 をシミュレーションするための操作
(1) ngspice の起動
(2) 「file」>「open」から n41.cir を開く
(3) 「file」>「run」 コマンドによるシミュレーションの実行
(4) 「Graph」>「Select Vector」コマンドを選ぶ
--->すると,表示すべき電圧を聞いてくる。
 今回は時間特性なので,縦軸はリニアな目盛りである。
(5) v(1)-v(2) v(2)-v(3) v(3) と打ち込む
(6) (お好みで)「Command」>「Edit source」から編集すればパラメタを変えられる。


・回路理論では,s という記号を用いて解析する。例えば:
 V1 = sL i + Ri + i/(sC)                (1)

・(1)式は,次のように書き換えることが出来る。
 s
2
L i = - s i R - i/C + s V1           (2)

・ところで,s という記号は 微分 という作用を持つことが知られている。
 電流 i の変数 x への置き換えも実施すると,(3)式が得られる。
L d2x
dt2
= - R dx
dt
- x
C
+ d V1
dt
 		
(3)
・(3)式において,次の置き換えを行うと,
この式はバネと重りとダンパから成る力学系を記述したものであり,
その解はRLC回路の時と同様に減衰振動をする。

 変 位 x ⇔ 電流 i
 質 量 m ⇔ コイルのリアクタンス H
 ダンパ d ⇔ 抵抗値 R
バネ定数 k ⇔ 容量値の逆数 1/C
 外 力 F ⇔ 外部電圧 V1 を微分したもの
m d2x
dt2
= - d dx
dt
- k x + F
 		
(4)
Download_kadai20110111.cir Download_kadai20110125.cir